마이크로폰 액션

01. 소리 질러~~

스마트 폰의 마이크로 입력되는 소리의 크기에 따라 알버트 로봇을 움직여 보자.

스마트 폰의 마이크에 입으로 후~ 불면 알버트 로봇이 뒤로 물러나는 프로그램을 작성하시오.

새 프로젝트 만들기를 참고하여 안드로이드 프로젝트와 플래시 파일을 만들고, setOnInitialized(callback:Function) 메소드와 setOnExecute(callback:Function) 메소드를 사용하여 콜백 함수를 등록하자. 또한, 플래시가 종료될 때 호출되는 리스너 함수를 등록하고, activate() 메소드를 호출하여 스마트 로봇 론처와 연결하도록 하자.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();

 function onInitialized(robot:Robot):void
 {
 }

 function onExecute():void
 {
 }

 function handleDeactivate(evt:Event):void
 {
     SmartRobot.deactivate();
 }

Microphone 액션의 객체를 얻기 위해서는 Action 클래스의 obtain(actionId:String) 메소드에서 actionId에 Action.Microphone.ID를 입력하면 된다.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var action:Action = Action.obtain(Action.Microphone.ID); // 액션 객체를 얻는다.
 action.activate(); // 액션을 시작한다.

 function onInitialized(robot:Robot):void
 {
 }

 function onExecute():void
 {
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate(); // 액션을 중지한다.
     action.dispose(); // 액션을 폐기한다.
     SmartRobot.deactivate();
 }

handleDeactivated 메소드에서 액션을 중지 및 폐기하였지만 어디에서 해도 상관은 없다. 플래시가 종료되기 전에 액션을 모두 폐기하여야 한다는 것만 잊지 않도록 하자.

Microphone 액션에는 스마트 폰의 마이크로 입력된 소리의 크기를 읽는 디바이스로 SENSOR_LEVEL이 있다. 입력된 소리의 파워를 데시벨로 나타내며, -100부터 0까지의 값을 가지는데 소리의 파워가 커질수록 값이 커진다.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;
 import org.roboid.robot.Device;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var action:Action = Action.obtain(Action.Microphone.ID);
 var levelDevice:Device = action.findDeviceById(Action.Microphone.SENSOR_LEVEL);
 action.activate();

 function onInitialized(robot:Robot):void
 {
 }

 function onExecute():void
 {
     var level:Number = levelDevice.readFloat();
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate();
     action.dispose();
     SmartRobot.deactivate();
 }

이제 스마트 폰의 마이크로 입력된 소리의 크기에 따라 알버트 로봇을 움직여 보도록 하자.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;
 import org.roboid.robot.Device;
 import kr.robomation.physical.Albert;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var leftWheelDevice:Device;
 var rightWheelDevice:Device;
 
 var action:Action = Action.obtain(Action.Microphone.ID);
 var levelDevice:Device = action.findDeviceById(Action.Microphone.SENSOR_LEVEL);
 action.activate();

 function onInitialized(robot:Robot):void
 {
     leftWheelDevice = robot.findDeviceById(Albert.EFFECTOR_LEFT_WHEEL);
     rightWheelDevice = robot.findDeviceById(Albert.EFFECTOR_RIGHT_WHEEL);
 }

 function onExecute():void
 {
     var level:Number = levelDevice.readFloat();
     if(level > -10)
     {
         leftWheelDevice.write(-20);
         rightWheelDevice.write(-20);
     }
     else
     {
         leftWheelDevice.write(0);
         rightWheelDevice.write(0);
     }
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate();
     action.dispose();
     SmartRobot.deactivate();
 }

스마트 로봇 론처를 실행하여 로봇과 연결한 후 애플리케이션을 실행하자. 스마트 폰을 알버트 로봇에 올려 놓고 스마트 폰의 마이크에 입으로 후~ 불면 작고 앙증맞은 알버트 로봇이 바람에 날려 뒤로 밀리는 것을 볼 수 있다. 너무 세게 불면 머리가 아프니까 경계값 -10을 변경하면서 적절한 값을 찾아 보도록 하자.

액션의 경우에도 로봇과 마찬가지로 리스너 함수를 통해 디바이스의 데이터를 얻을 수 있다. 이를 위해서는 우선 addDeviceDataChangedListener(listener:Function) 메소드를 사용하여 액션에 리스너 함수를 등록해야 한다.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;
 import org.roboid.robot.Device;
 import kr.robomation.physical.Albert;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.activate();
 
 var leftWheelDevice:Device;
 var rightWheelDevice:Device;
 
 var action:Action = Action.obtain(Action.Microphone.ID);
 action.addDeviceDataChangedListener(onDeviceDataChanged);
 var levelDevice:Device = action.findDeviceById(Action.Microphone.SENSOR_LEVEL);
 action.activate();

 function onInitialized(robot:Robot):void
 {
     leftWheelDevice = robot.findDeviceById(Albert.EFFECTOR_LEFT_WHEEL);
     rightWheelDevice = robot.findDeviceById(Albert.EFFECTOR_RIGHT_WHEEL);
 }

 function onDeviceDataChanged(device:Device, values:Array, timestamp:int)
 {
     var level:int;
     switch(device.getId())
     {
     case Action.Microphone.SENSOR_LEVEL:
         level = values[0];
         if(level > -10)
         {
             leftWheelDevice.write(-20);
             rightWheelDevice.write(-20);
         }
         else
         {
             leftWheelDevice.write(0);
             rightWheelDevice.write(0);
         }
         break;
     }
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate();
     action.dispose();
     SmartRobot.deactivate();
 }