음성 합성 액션

01. 인사하기

작고 예쁜 알버트 로봇이 인사를 하면 귀여울 것 같다. 좌우로 몸을 움직여 애교를 부리면서 인사하도록 해보자.

새 프로젝트 만들기를 참고하여 안드로이드 프로젝트와 플래시 파일을 만들고, setOnInitialized(callback:Function) 메소드와 setOnExecute(callback:Function) 메소드를 사용하여 콜백 함수를 등록하자. 또한, 플래시가 종료될 때 호출되는 리스너 함수를 등록하고, activate() 메소드를 호출하여 스마트 로봇 론처와 연결하도록 하자.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();

 function onInitialized(robot:Robot):void
 {
 }

 function onExecute():void
 {
 }

 function handleDeactivate(evt:Event):void
 {
     SmartRobot.deactivate();
 }

Tts 액션의 객체를 얻기 위해서는 Action 클래스의 obtain(actionId:String) 메소드에서 actionId에 Action.Tts.ID를 입력하면 된다.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var action:Action = Action.obtain(Action.Tts.ID); // 액션 객체를 얻는다.
 action.activate(); // 액션을 시작한다.

 function onInitialized(robot:Robot):void
 {
 }

 function onExecute():void
 {
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate(); // 액션을 중지한다.
     action.dispose(); // 액션을 폐기한다.
     SmartRobot.deactivate();
 }

handleDeactivated 메소드에서 액션을 중지 및 폐기하였지만 어디에서 해도 상관은 없다. 플래시가 종료되기 전에 액션을 모두 폐기하여야 한다는 것만 잊지 않도록 하자.

Tts 액션에는 음성 합성할 문자열을 쓰는 디바이스로 COMMAND_TEXT가 있다.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;
 import org.roboid.robot.Device;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var action:Action = Action.obtain(Action.Tts.ID);
 var textDevice:Device = action.findDeviceById(Action.Tts.COMMAND_TEXT);
 textDevice.writeString("Hello");
 action.activate();

 function onInitialized(robot:Robot):void
 {
 }

 function onExecute():void
 {
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate();
     action.dispose();
     SmartRobot.deactivate();
 }

알버트 로봇의 몸도 좌우로 움직여 보도록 하자.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;
 import org.roboid.robot.Device;
 import kr.robomation.physical.Albert;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var leftWheelDevice:Device;
 var rightWheelDevice:Device;
 var count:int = 0;
 
 var action:Action = Action.obtain(Action.Tts.ID);
 var textDevice:Device = action.findDeviceById(Action.Tts.COMMAND_TEXT);
 textDevice.writeString("Hello");
 action.activate();

 function onInitialized(robot:Robot):void
 {
     leftWheelDevice = robot.findDeviceById(Albert.EFFECTOR_LEFT_WHEEL);
     rightWheelDevice = robot.findDeviceById(Albert.EFFECTOR_RIGHT_WHEEL);
 }

 function onExecute():void
 {
     if((++count / 50) % 2 == 0)
     {
         leftWheelDevice.write(20);
         rightWheelDevice.write(-20);
     }
     else
     {
         leftWheelDevice.write(-20);
         rightWheelDevice.write(20);
     }
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate();
     action.dispose();
     SmartRobot.deactivate();
 }

인사가 끝났는데 몸을 계속 움직이니 이상하다. 음성 출력이 끝날 때 정지하도록 해보자.

Action 클래스의 setOnCompletedListener(listener:Function) 메소드를 사용하여 Tts 액션의 음성 출력이 끝날 때 호출되는 리스너 함수를 등록할 수 있다.

 import flash.events.Event;
 import org.smartrobot.android.SmartRobot;
 import org.roboid.robot.Robot;
 import org.smartrobot.android.action.Action;
 import org.roboid.robot.Device;
 import kr.robomation.physical.Albert;

 NativeApplication.nativeApplication.addEventListener(Event.DEACTIVATE, handleDeactivate, false, 0, true);
 SmartRobot.setOnInitialized(onInitialized);
 SmartRobot.setOnExecute(onExecute);
 SmartRobot.activate();
 
 var leftWheelDevice:Device;
 var rightWheelDevice:Device;
 var count:int = 0;
 var completed:Boolean = false;
 
 var action:Action = Action.obtain(Action.Tts.ID);
 action.setOnCompletedListener(onActionCompleted);
 var textDevice:Device = action.findDeviceById(Action.Tts.COMMAND_TEXT);
 textDevice.writeString("Hello");
 action.activate();

 function onInitialized(robot:Robot):void
 {
     leftWheelDevice = robot.findDeviceById(Albert.EFFECTOR_LEFT_WHEEL);
     rightWheelDevice = robot.findDeviceById(Albert.EFFECTOR_RIGHT_WHEEL);
 }

 function onExecute():void
 {
     if(completed)
     {
         leftWheelDevice.write(0);
         rightWheelDevice.write(0);
     }
     else
     {
         if((++count / 50) % 2 == 0)
         {
             leftWheelDevice.write(20);
             rightWheelDevice.write(-20);
         }
         else
         {
             leftWheelDevice.write(-20);
             rightWheelDevice.write(20);
         }
     }
 }

 function onActionCompleted(action:Action):void
 {
     completed = true;
 }

 function handleDeactivate(evt:Event):void
 {
     action.deactivate();
     action.dispose();
     SmartRobot.deactivate();
 }